Development

Communication / LoRa:

» SX 06a: TX Frame ACK

This example shows how to configure the SX1272 module in LoRa mode and then send packets with Waspmote Frames within the payload using ACKs.

Required Materials

1 x Waspmote PRO
1 x Battery
1 x MiniUSB wire
1 x SX1272 module (LoRa)
1 x Receiver module with SX_06b example

Notes

- The SX1272 module is provided with a special 4.5 dBi antenna, which enables maximum range. The only exception is Smart Parking; in this case the antenna is smaller, 0 dBi, to fit inside the enclosure.
- It is not recommended to work without an antenna screwed to the module. The module could be damaged due to RF reflections.
- The SX1272 module can only be used in special Waspmote units which have been modified to drive the SPI pins to SOCKET0. (only SOCKET0 is available for SX1272)
- This module does not save the configuration. So, the network settings as the mode or the channel MUST be configured every time it is switched on.
- This example can be executed in Waspmote v12 and Waspmote v15

Code

/*  
 *  ------ [SX_06a] - TX LoRa with Waspmote Frame and ACKs -------- 
 *
 *  Explanation: This example shows how to configure the semtech 
 *  module in LoRa mode and then send packets with Waspmote Frames
 *  within the payload using ACKs.
 *  
 *  Copyright (C) 2016 Libelium Comunicaciones Distribuidas S.L. 
 *  http://www.libelium.com 
 *  
 *  This program is free software: you can redistribute it and/or modify  
 *  it under the terms of the GNU General Public License as published by  
 *  the Free Software Foundation, either version 3 of the License, or  
 *  (at your option) any later version.  
 *   
 *  This program is distributed in the hope that it will be useful,  
 *  but WITHOUT ANY WARRANTY; without even the implied warranty of  
 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the  
 *  GNU General Public License for more details.  
 *   
 *  You should have received a copy of the GNU General Public License  
 *  along with this program.  If not, see <http://www.gnu.org/licenses/>.  
 *  
 *  Version:           0.2
 *  Design:            David Gascón 
 *  Implementation:    Covadonga Albiñana, Yuri Carmona
 */
     
// Include these libraries to transmit frames with sx1272
#include <WaspSX1272.h>
#include <WaspFrame.h>

// Define private key to encrypt message  
char nodeID[] = "node_001"; 

// define the destination address to send packets
uint8_t rx_address = 2;

// status variable
int8_t e;


void setup()
{
  // Init USB port
  USB.ON();
  USB.println(F("SX_06a example"));
  USB.println(F("Semtech SX1272 module. TX LoRa with Waspmote Frame using ACKs"));

  // set the node ID
  frame.setID(nodeID); 


  USB.println(F("----------------------------------------"));
  USB.println(F("Setting configuration:")); 
  USB.println(F("----------------------------------------"));
  
  // Init SX1272 module
  sx1272.ON();

  // Select frequency channel
  e = sx1272.setChannel(CH_11_868);
  USB.print(F("Setting Channel CH_11_868.\t state ")); 
  USB.println(e);

  // Select implicit (off) or explicit (on) header mode
  e = sx1272.setHeaderON();
  USB.print(F("Setting Header ON.\t\t state "));  
  USB.println(e); 

  // Select mode: from 1 to 10
  e = sx1272.setMode(1);  
  USB.print(F("Setting Mode '1'.\t\t state "));
  USB.println(e);  

  // select CRC on or off
  e = sx1272.setCRC_ON();
  USB.print(F("Setting CRC ON.\t\t\t state "));
  USB.println(e);  

  // Select output power (Max, High or Low)
  e = sx1272.setPower('H');
  USB.print(F("Setting Power to 'H'.\t\t state "));  
  USB.println(e); 

  // Select the node address value: from 2 to 255
  e = sx1272.setNodeAddress(5);
  USB.print(F("Setting Node Address to '5'.\t state "));
  USB.println(e);
  USB.println();

  delay(1000);  

  USB.println(F("----------------------------------------"));
  USB.println(F("Sending:")); 
  USB.println(F("----------------------------------------"));
}


void loop()
{
  ////////////////////////////////////////////////
  // 1. Create a new Frame with sensor fields
  ////////////////////////////////////////////////

  USB.println(F("Create new Frame:"));  
  
  // Creating frame to send
  frame.createFrame(ASCII);

  // Adding sensor battery
  frame.addSensor(SENSOR_BAT, (uint8_t) PWR.getBatteryLevel());

  // Show frame via USB port
  frame.showFrame(); 
  
  
  ////////////////////////////////////////////////////////////////
  // 2. Send Frame to another Waspmote
  ////////////////////////////////////////////////////////////////

  // Sending packet 
  e = sx1272.sendPacketTimeoutACK( rx_address, frame.buffer, frame.length);

  // Check sending status
  if (e == 0)
  {
    USB.println(F("Packet sent OK"));    
  }
  else 
  {
    USB.println(F("Error sending the packet"));  
    USB.print(F("state: "));
    USB.println(e, DEC);
  } 
  
  USB.println();
  delay(1000); 
    
}

Output

H#
SX_06a example
Semtech SX1272 module. TX LoRa with Waspmote Frame using ACKs
----------------------------------------
Setting configuration:
----------------------------------------
Setting Channel CH_11_868. state 0
Setting Header ON. state 0
Setting Mode '1'. state 0
Setting CRC ON. state 0
Setting Power to 'H'. state 0
Setting Node Address to '5'. state 0

----------------------------------------
Sending:
----------------------------------------
Create new Frame:
===============================
Current ASCII Frame:
Length: 34
Frame Type: 128
frame (HEX): 3C3D3E800123333837323536303030236E6F64655F3030312330234241543A393823
frame (STR): <=>€#387256000#node_001#0#BAT:98#
===============================
Packet sent OK

Create new Frame:
===============================
Current ASCII Frame:
Length: 34
Frame Type: 128
frame (HEX): 3C3D3E800123333837323536303030236E6F64655F3030312331234241543A393923
frame (STR): <=>€#387256000#node_001#1#BAT:99#
===============================
Packet sent OK

Create new Frame:
===============================
Current ASCII Frame:
Length: 34
Frame Type: 128
frame (HEX): 3C3D3E800123333837323536303030236E6F64655F3030312332234241543A393923
frame (STR): <=>€#387256000#node_001#2#BAT:99#
===============================
Packet sent OK

...

Quick Publish: