Development v12

Warning - Product Update

All the resources present on this section belong to Waspmote v12, Waspmote Plug & Sense! v12 and Meshlium v3.8.

If you have a Waspmote v15, Waspmote Plug & Sense! v15 or Meshlium v4.0 please go to the new Development Section.

Check what is your version and what are the differences between the old and the new one in this document.

» 3G 26: Sending email with SMTP

This example shows how to send an email with SMTP and how to attach a file to the email

Required Materials

1 x Waspmote
1 x battery
1 x 3G + GPS module
1 x SIM card
1 x GPRS/3G antenna

Notes

- 3G module must be powered with a battery
- When 3G is in use, interrupts can't be used
- The email servers must work without SSL function
- This example can be executed in Waspmote v12 and Waspmote v15

Code

/*  
 *  --------------- 3G_26 - Sending email with SMTP ----------------- 
 *  
 *  Explanation: This example shows how to send an email with SMTP and 
 *  how to attach a file to the email.
 *  
 *  Copyright (C) 2014 Libelium Comunicaciones Distribuidas S.L. 
 *  http://www.libelium.com 
 *  
 *  This program is free software: you can redistribute it and/or modify 
 *  it under the terms of the GNU General Public License as published by 
 *  the Free Software Foundation, either version 3 of the License, or 
 *  (at your option) any later version. 
 *  
 *  This program is distributed in the hope that it will be useful, 
 *  but WITHOUT ANY WARRANTY; without even the implied warranty of 
 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the 
 *  GNU General Public License for more details. 
 *  
 *  You should have received a copy of the GNU General Public License 
 *  along with this program.  If not, see <http://www.gnu.org/licenses/>. 
 *  
 *  Version:           1.1
 *  Design:            David Gascón 
 *  Implementation:    Alejandro Gállego 
 */


#include "Wasp3G.h"

char apn[] = "apn";
char login[] = "login";
char password[] = "password";

int count=0;
int answer=0;

char picture_name[30];

void setup()
{
    USB.println(F("**************************"));
    // 1. sets operator parameters
    _3G.set_APN(apn, login, password);
    // And shows them
    _3G.show_APN();
    USB.println(F("**************************"));
}



void loop(){ 

    USB.ON();
    USB.println(F("Starting"));

    // 2. activates the 3G module:
    answer = _3G.ON();
    if ((answer == 1) || (answer == -3))
    {
        USB.println(F("3G module ready..."));

        _3G.setTime();
        // 3. sets pin code
        USB.println(F("Setting PIN code..."));
        // **** must be substituted by the SIM code
        if (_3G.setPIN("****") == 1) 
        {
            USB.println(F("PIN code accepted"));
        }
        else
        {
            USB.println(F("PIN code incorrect"));
        } 

        USB.print(F("Connecting to the network..."));    

        // 4. waits for connection to the network
        answer = _3G.check(180);    
        if (answer == 1)
        { 
            USB.println(F("connected"));    

            // 5. Sets SMTP parameters
            USB.print(F("Setting SMTP server parameters..."));
            answer = _3G.setSMTPserver("SMTP server", server_port, "STMP_account", "password");
            if (answer == 1)
            {
                USB.println(F("done"));

                // 6. Sets email parameters
                USB.print(F("Setting e-mail parameters..."));
                answer = _3G.setSMTPfrom("sender address", "sender");
                answer += _3G.setSMTPrecipient(0, 0, "recipient address", "TO");
                answer += _3G.setSMTPsubject("subject");
                answer += _3G.setSMTPbody("body");
                if (answer == 4)
                {   
                    USB.println(F("done"));
                    USB.print(F("Attaching the picture..."));
                    // Goes to the pictures folder into the SD  card
                    _3G.goRoot(1);
                    _3G.cd("Picture");
                    // 7. Attachs a picture
                    if (_3G.setSMTPattach( 1, picture_name) == 1)
                    {
                        USB.println(F("done"));                        
                        USB.print(F("Sending the e-mail..."));
                        // 8. Sends the email
                        if ( _3G.setSMTPsend() == 1)
                        {                            
                            USB.println(F("done!"));
                        }
                        else
                        {
                            USB.println(F("fail"));
                        }
                    }
                    else
                    {
                        USB.println(F("fail"));
                    }
                }
                else
                {
                    USB.println(F("fail"));
                }            
            }
            else
            {
                USB.print(F("fail. Error code:"));
                USB.println(answer, DEC);
            }
        }
        else
        {
            USB.println(F("3G module cannot connect to the network..."));
        }
    }
    else
    {
        // Problem with the communication with the 3G module
        USB.println(F("3G module not started"));
    }

    // 9. Powers off the 3G module
    _3G.OFF();

    USB.println(F("Sleeping..."));

    // 10. sleeps one hour:
    PWR.deepSleep("00:01:00:00", RTC_OFFSET, RTC_ALM1_MODE1, ALL_OFF);


}

Output

Starting
3G module ready...
Setting PIN code...
PIN code accepted
Connecting to the network...connected
Setting SMTP server parameters...done
Setting e-mail parameters...done
Attaching the picture...done
Sending the e-mail...done!
Sleeping...

Quick Publish: