Development v12

Warning - Product Update

All the resources present on this section belong to Waspmote v12, Waspmote Plug & Sense! v12 and Meshlium v3.8.

If you have a Waspmote v15, Waspmote Plug & Sense! v15 or Meshlium v4.0 please go to the new Development Section.

Check what is your version and what are the differences between the old and the new one in this document.

» 868 08b: Complete example RX

This is a complete example for XBee 868. This example shows how to receive a packet. When the source address is the expected one, an answer is sent back to the sending Waspmote

Required Materials

1 x Waspmote
1 x Battery
1 x MiniUSB wire
1 x XBee-868

Notes

- This example belongs to a two-code example. This is the receiving part.
- All XBee modules must be configured with the same network parameters (PANID and encryption mode)
- This example can be executed in Waspmote v12 and Waspmote v15

Code

/*  
 *  ------ [868_08b] - complete example receive  ------
 *  
 *  Explanation: This is a complete example for XBee-868
 *  This example shows how to receive a packet. When the source 
 *  address is the expected one, an answer is sent back to the
 *  emitter Waspmote
 *  
 *  Copyright (C) 2015 Libelium Comunicaciones Distribuidas S.L. 
 *  http://www.libelium.com 
 *  
 *  This program is free software: you can redistribute it and/or modify 
 *  it under the terms of the GNU General Public License as published by 
 *  the Free Software Foundation, either version 3 of the License, or 
 *  (at your option) any later version. 
 *  
 *  This program is distributed in the hope that it will be useful, 
 *  but WITHOUT ANY WARRANTY; without even the implied warranty of 
 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the 
 *  GNU General Public License for more details. 
 *  
 *  You should have received a copy of the GNU General Public License 
 *  along with this program.  If not, see <http://www.gnu.org/licenses/>. 
 *  
 *  Version:           0.2
 *  Design:            David Gascón 
 *  Implementation:    Yuri Carmona
 */

#include <WaspXBee868.h>
#include <WaspFrame.h>

// define variable
uint8_t error;
uint8_t destination[8];


void setup()
{
  // init USB port
  USB.ON();
  USB.println(F("Complete example (RX node)"));

  // init XBee 
  xbee868.ON();
}


void loop()
{

  // receive XBee packet (wait message for 20 seconds)
  error = xbee868.receivePacketTimeout( 20000 );

  // check answer  
  if( error == 0 ) 
  {    
    USB.println(F("\n1. New packet received"));
    
    // Show data stored in '_payload' buffer indicated by '_length'
    USB.print(F("--> Data: "));  
    USB.println( xbee868._payload, xbee868._length);
    
    // Show data stored in '_payload' buffer indicated by '_length'
    USB.print(F("--> Length: "));  
    USB.println( xbee868._length,DEC);


    /*** Available info in library structure ***/

    // get Source's MAC address
    destination[0] = xbee868._srcMAC[0]; 
    destination[1] = xbee868._srcMAC[1]; 
    destination[2] = xbee868._srcMAC[2]; 
    destination[3] = xbee868._srcMAC[3]; 
    destination[4] = xbee868._srcMAC[4]; 
    destination[5] = xbee868._srcMAC[5]; 
    destination[6] = xbee868._srcMAC[6]; 
    destination[7] = xbee868._srcMAC[7]; 
    
    
    // Show data stored in '_payload' buffer indicated by '_length'
    USB.print(F("--> Source MAC address: "));      
    USB.printHex( destination[0] );    
    USB.printHex( destination[1] );    
    USB.printHex( destination[2] );    
    USB.printHex( destination[3] );    
    USB.printHex( destination[4] );    
    USB.printHex( destination[5] );    
    USB.printHex( destination[6] );    
    USB.printHex( destination[7] );    
    USB.println();
    
    // insert small delay to wait TX node 
    // to prepare to receive messages
    delay(1000);
    

    /*** Send message to TX node ***/
    
    USB.println(F("\n2. Send a response to the TX node: ")); 
    
    // send XBee packet
    error = xbee868.send( destination, "Message_from_RX_node" );       

    // check TX flag
    if( error == 0 )
    {
      USB.println(F("send ok"));

      // blink green LED
      Utils.blinkGreenLED();
    }
    else 
    {
      USB.println(F("send error"));

      // blink red LED
      Utils.blinkRedLED();
    }
  }
  else
  {
    // Print error message:
    /*
     * '7' : Buffer full. Not enough memory space
     * '6' : Error escaping character within payload bytes
     * '5' : Error escaping character in checksum byte
     * '4' : Checksum is not correct	  
     * '3' : Checksum byte is not available	
     * '2' : Frame Type is not valid
     * '1' : Timeout when receiving answer   
     */
    USB.print(F("Error receiving a packet:"));
    USB.println(error,DEC);     
  }
  
  
  USB.println(F("\n----------------------------------"));
}

Output

H#
Complete example (RX node)

1. New packet received
--> Data: <=>€#387245265#node_TX#0#STR:Complete example message#BAT:33#
--> Length: 62
--> Source MAC address: 0013A20040894746

2. Send a response to the TX node:
send ok

----------------------------------
...

Quick Publish: