Development v12

Warning - Product Update

All the resources present on this section belong to Waspmote v12, Waspmote Plug & Sense! v12 and Meshlium v3.8.

If you have a Waspmote v15, Waspmote Plug & Sense! v15 or Meshlium v4.0 please go to the new Development Section.

Check what is your version and what are the differences between the old and the new one in this document.

» 900 08a: Complete example TX

This is a complete example for XBee-900Mhz. This example shows how to send a packet using unicast 64-bit destination address. After sending the packet, Waspmote waits for the response of the receiver and prints all available information

Required Materials

1 x Waspmote PRO
1 x Battery
1 x MiniUSB wire
1 x XBee-900

Notes

* This example belongs to a two-code example. This is the sending part.
* Both XBee modules must be configured with the same network parameters (PANID, channel, encryption mode)

Code

/*  
 *  ------ [900_08a] - complete example send  ------
 *  
 *  Explanation: This is a complete example for XBee-900Mhz.
 *  This example shows how to send a packet using unicast 64-bit
 *  destination address. After sending the packet, Waspmote waits
 *  for the response of the receiver and prints all available 
 *  information  
 *  
 *  Copyright (C) 2015 Libelium Comunicaciones Distribuidas S.L. 
 *  http://www.libelium.com 
 *  
 *  This program is free software: you can redistribute it and/or modify 
 *  it under the terms of the GNU General Public License as published by 
 *  the Free Software Foundation, either version 3 of the License, or 
 *  (at your option) any later version. 
 *  
 *  This program is distributed in the hope that it will be useful, 
 *  but WITHOUT ANY WARRANTY; without even the implied warranty of 
 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the 
 *  GNU General Public License for more details. 
 *  
 *  You should have received a copy of the GNU General Public License 
 *  along with this program.  If not, see <http://www.gnu.org/licenses/>. 
 *  
 *  Version:           0.2
 *  Design:            David Gascón 
 *  Implementation:    Yuri Carmona
 */

#include <WaspXBee900.h>
#include <WaspFrame.h>


// Destination MAC address
//////////////////////////////////////////
char RX_ADDRESS[] = "0013A2004066EF95";
//////////////////////////////////////////

// define variable
uint8_t error;



void setup()
{
  // init USB port
  USB.ON();
  USB.println(F("Complete example (TX node)"));

  // set Waspmote identifier
  frame.setID("node_TX");

  // init XBee
  xbee900.ON();

}


void loop()
{ 
  //////////////////////////
  // 1. create frame
  //////////////////////////  

  // 1.1. create new frame
  frame.createFrame(ASCII);  

  // 1.2. add frame fields
  frame.addSensor(SENSOR_STR, "Complete example message"); 
  frame.addSensor(SENSOR_BAT, PWR.getBatteryLevel() ); 
  
  USB.println(F("\n1. Created frame to be sent"));
  frame.showFrame();

  //////////////////////////
  // 2. send packet
  //////////////////////////  

  // send XBee packet
  error = xbee900.send( RX_ADDRESS, frame.buffer, frame.length );   
  
  USB.println(F("\n2. Send a packet to the RX node: "));
  
  // check TX flag
  if( error == 0 )
  {
    USB.println(F("send ok"));
    
    // blink green LED
    Utils.blinkGreenLED();    
  }
  else 
  {
    USB.println(F("send error"));
    
    // blink red LED
    Utils.blinkRedLED();  
  }


  //////////////////////////
  // 3. receive answer
  //////////////////////////  
  
  USB.println(F("\n3. Wait for an incoming message"));
  
  // receive XBee packet
  error = xbee900.receivePacketTimeout( 10000 );

  // check answer  
  if( error == 0 ) 
  {
    // Show data stored in '_payload' buffer indicated by '_length'
    USB.print(F("--> Data: "));  
    USB.println( xbee900._payload, xbee900._length);
    
    // Show data stored in '_payload' buffer indicated by '_length'
    USB.print(F("--> Length: "));  
    USB.println( xbee900._length,DEC);
    
    // Show data stored in '_payload' buffer indicated by '_length'
    USB.print(F("--> Source MAC address: "));      
    USB.printHex( xbee900._srcMAC[0] );    
    USB.printHex( xbee900._srcMAC[1] );    
    USB.printHex( xbee900._srcMAC[2] );    
    USB.printHex( xbee900._srcMAC[3] );    
    USB.printHex( xbee900._srcMAC[4] );    
    USB.printHex( xbee900._srcMAC[5] );    
    USB.printHex( xbee900._srcMAC[6] );    
    USB.printHex( xbee900._srcMAC[7] );    
    USB.println();
  }
  else
  {
    // Print error message:
    /*
     * '7' : Buffer full. Not enough memory space
     * '6' : Error escaping character within payload bytes
     * '5' : Error escaping character in checksum byte
     * '4' : Checksum is not correct	  
     * '3' : Checksum byte is not available	
     * '2' : Frame Type is not valid
     * '1' : Timeout when receiving answer   
    */
    USB.print(F("Error receiving a packet:"));
    USB.println(error,DEC);     
  }
  
  // wait for 5 seconds
  USB.println(F("\n----------------------------------"));
  delay(5000);

}

Output

E#
Complete example (TX node)

1. Created frame to be sent
===============================
Current ASCII Frame:
Length: 62
Frame Type: 128
frame (HEX): 3C3D3E800223333837323435323635236E6F64655F54582330235354523A436F6D706C657465206578616D706C65206D657373616765234241543A333423
frame (STR): <=>€#387245265#node_TX#0#STR:Complete example message#BAT:34#
===============================

2. Send a packet to the RX node:
send ok

3. Wait for an incoming message
--> Data: Message_from_RX_node
--> Length: 20
--> Source MAC address: 0013A2004066EF95

----------------------------------

Quick Publish: